7thSense Delta Media Server

Valid tests are   =  !=   and   or   <   >   <=   >=   &   |

if ($myvar = $myvar2)
    if ($myvar = 2)
    if (2 = $myvar)
    if ($myvar > $myvar2)
    if ($myvar and 1)
    if ($myvar!=2)
    if ($mystringvar="mystring")
    if ($myvar < $absoluteframe[0])
    

Global Variables can be int, float or string

globalvar $myintvar = 1
    globalvar $myfloatvar = 6.54
    globalvar $mystringvar = "movie"

    globalvar $myintvar = 1 readonly
    // adding readonly will create a variable at that value, which will not be written to the registry thereafter


    globalvar $myintvar = 1 watched
    // adding watched after will make this variable watched in the debugging area, creating a global var which
    already exists will do nothing
    

$myvar = $seqrandom[4,40]
    // sets $myvar to a random value between 4 & 40 inclusive

    $myvar = $absoluteframe[2]
    // sets $myvar to the current absolute frame of timeline 2

    $mystringvar = $absoluteframe[1] smpte
    // sets $mystringvar to the current absolute frame in smpte mode of timeline 1

    $mystringvar = $absoluteframe[1] digits=5
    // sets $mystringvar to the current absolute frame formatted to 5 digits where possible

    $mystringvar = $currenttime
    // sets $mystringvar to the current clock time of the server

    $mystringvar = $intcurrenttime
    // sets $mystringvar to the current clock time of the server as an integer

    $mystringvar = $currentdate
    // sets $mystringvar to the current date in dd/mm/yyyy

    $mystringvar = $currentdate usa
    // sets $mystringvar to the current date in mm/dd/yyyy

    $replacevarmode = [0/1]
    // 0 is the default search replace mode, 1 is a simple string replace mode

    $mystringvar = $seqplaymode[2]
    // sets $mystringvar to the playmode for that timeline, e.g. "Play", "Stop", "Ready to Play",
 "Preparing to Play"

    $mystringvar = $seqautoplaymode[2]
    // sets $mystringvar to the Autoplaymode for that timeline,"Play" or "Stop"

    $myvar = $seqreserve
    // sets $myvar to 0 if not in reserve or 1 if in reserve

    $mystringvar = $timetoresource resourcename [smpte / seconds]
    // sets $mystringvar to the time to the named resource, in number of frames (by default),
 or seconds / smpte timecode with optional parameters

    $myintvar = $extctrlcomms
    // Set to 1 if external control comms is enabled, 0 if external control comms is disabled 
(set using the EXTCTRLCOMMS command)

    $myfloatvar = $currentframerate
    // Sets $myfloatvar to the current frame rate

    

$myval++
    $myval--
    

$myintvar = 12
    #start // label is designated by #
    if ($myintvar>0)
    {
      $myintvar--
      // do something 12 times
      gotolabel #start
    }
    

You can also use gotoline X where X is a line number within the sequence

timeangles($hourangle,$minuteangle,$secondangle,$offsetangle )
    // timeangles returns the angles for an hour, minute & second hand in an analogue clock, with an
    // optional offsetangle parameter
    // By default, offsetangle is 0, to get 12 midnight straight up, use -90 as an offsetangle.

    angletoxy($secondangle,$radius,$x,$y)
    // angletoxy works out the x & y position around a centrepoint for a specific angle.
    // set radius to the desired circle radius.
    

globalvar $clock = "01:01:01"
    // create string variable for clock string

    #start
    // create label to jump back to

    $clock = $currenttime
    // get current server time into $clock variable

    textparams RTC $clock
    // set the RTC text resource to the $clock value

    delay 1s
    // delay 1s

    gotolabel #start
    // repeat until cancelled
            

globalvar $value = 0
    // create int variable for counter

    #start
    // create label to jump back to

    setartnetchannel channel=16 value=$value
    // Set channel 16 to current value

    $value++
    // increment value

    if ($value>255) // test if > 255
    {
      // if value>255, jump to end
      gotolabel #end
    }

    gotolabel #start
    // jump to start

    #end
    

globalvar $mystringvar = ""
    // create string variable

    $mystringvar = $timetoresource RTC smpte

    tracevar $mystringvar

    // For RTC resource at 00:00:05::00 and playhead at 00:00:03::00, outputs "$mystringvar = 00:00:02:00" to
    sequence editor trace window. If the time positions are reversed, outputs "$mystringvar = -00:00:02:00"

    

globalvar $hourangle = 0.0
    globalvar $minuteangle = 0.0
    globalvar $secondangle = 0.0
    globalvar $angle = 0.0
    globalvar $radius = 450.0
    globalvar $x  =0.0
    globalvar $y  =0.0
    globalvar $xoffset  =1000.0
    globalvar $yoffset  =500.0
    globalvar $offsetangle = -90.0

    // assumes a clock face centred on 1000,500, with 3 images named
    // hourhand, minutehand, secondhand also centred there.

    #START
    $startblock
    timeangles($hourangle,$minuteangle,$secondangle,$offsetangle )

    // move the 3 clock hands
    mediamove ctrlname=hourhand r=$hourangle
    mediamove ctrlname=minutehand r=$minuteangle
    mediamove ctrlname=secondhand r=$secondangle

    // make a small circular image follow the second hand, placed at the radius of the clock
    angletoxy($secondangle,$radius,$x,$y)
    // centre the movement over the clock
    $x = $x + $xoffset
    $y = $y + $yoffset
    mediamove ctrlname=circle_image x=$x y=$y

    $endblock
    delay 900ms

    gotolabel #START

    #END